BMW Standard Tools Installation

Mithilfe dieser Installationsdatei wird eine einfache Installation der BMW Standard Tools auf Windows 10/11 ermöglicht. Soweit wie möglich ist alles auf Deutsch eingestellt mit den entsprechenden Dateien. Folgende Tools sind vorhanden: Inpa | Tool32 | NcsExpert | NcsDummy| WinKFP | Coding Tool

Download

Installationsdatei herunterladen: BMW_Standard_Tools_Setup.exe (~100MB)

Installation

BMW_Standard_Tools_Setup.exe ausführen und auf Installieren klicken.

Abschluss

Die Installation der BWM Standard Tools ist nun abgeschlossen. Verknüpfungen zu den Programmen sollten auf dem Desktop zu finden sein.

Jetzt muss nur noch das OBD Kabel richtig mit dem Laptop konfiguriert bzw. das INPA Interface einstellt werden, damit sich INPA richtig mit dem Auto verbinden und kommunizieren kann.

INPA Interface einstellen: bmwtools.pages.dev/obd

Das benötigte Kabel kann z.B. an dieser Stelle bezogen werden: obdexpert.de

Hinweise zur Installation

Nach ausführlicher Analyse der unterschiedlichen Parameter und Optionen habe ich einen Installer erstellt, der die Installation der BMW Standard Tools erheblich vereinfacht.

Der Installer wurde auf Windows 10/11 64-Bit Systemen getestet.
Sämtliche Vorgänge und Details sind live im Setup einzusehen.
Zu Beginn der Installation werden alle Installationsdateien entpackt, was einen gewissen Zeitraum in Anspruch nehmen kann.
Es erscheint kurz ein Fenster zur Datensicherung, dieses wird normalerweise sofort automatisch bestätigt, sollte dies nicht der Fall sein, muss es manuell mit OK bestätigt werden!
Der Installer benutzt veraltete Teile des Betriebssystems (OCX-Dateien aus der Zeit von Windows XP), die mit regsvr32.exe registriert werden. Manche Antivirenprogramme könnten diesen Prozess blockieren.

Script im neuen Setup

# Project website: https://bmwtools.pages.dev/
# Setup: NSIS (nsis.sourceforge.net)

!include MUI2.nsh
!include "LogicLib.nsh"

# Windows Message Constants
!define IDOK 1

# General Settings
Name "BMW Standard Tools"
OutFile "BMW_Standard_Tools_Setup.exe"
Unicode true
RequestExecutionLevel admin
ManifestDPIAware true
InstallDir "C:\"
BrandingText "bmwtools.pages.dev"

# Version Information
VIProductVersion "1.0.0.1"
VIAddVersionKey ProductName "BMW Standard Tools"
VIAddVersionKey LegalCopyright "bmwtools.pages.dev"
VIAddVersionKey FileDescription "BMW Standard Tools Installation"
VIAddVersionKey FileVersion "1.0.0.1"
VIAddVersionKey ProductVersion "1.0.0.1"
VIAddVersionKey OriginalFilename "BMW_Standard_Tools_Setup.exe"

# MUI Configuration
!define MUI_ICON "icon.ico"
!define MUI_HEADERIMAGE
!define MUI_HEADERIMAGE_BITMAP "header.bmp"
!define MUI_HEADERIMAGE_RIGHT
!define MUI_WELCOMEFINISHPAGE_BITMAP "wizard.bmp"

# Pages
!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_INSTFILES

# Custom Finish Page Configuration
!define MUI_FINISHPAGE_LINK "bmwtools.pages.dev"
!define MUI_FINISHPAGE_LINK_LOCATION "https://bmwtools.pages.dev"
!insertmacro MUI_PAGE_FINISH

!insertmacro MUI_LANGUAGE "German"

# Installer Section
Section "Main Installation" SEC_MAIN
    SectionIn RO

    # Extract files to TEMP
    SetOutPath "$TEMP\bmw_setup_files"
    File /r "bmw_setup_files\*.*"

    # Run Original BMW Inno Setup (jrsoftware.org)
    System::Call 'Kernel32::SetEnvironmentVariable(t "__COMPAT_LAYER", t "WinXP")'
    Exec '"$TEMP\bmw_setup_files\Standard_Tools_Setup_2.12.exe" /VERYSILENT /SUPPRESSMSGBOXES /NORESTART /LANG=de /NOICONS /TASKS=""'

    DetailPrint "Warte auf Installer..."
    Sleep 3000

    # Loop with 15-second timeout
    System::Call kernel32::GetTickCount()i .r0
    ${Do}
        System::Call kernel32::GetTickCount()i .r1
        IntOp $2 $1 - $0
        ${If} $2 >= 15000
            ${Break}
        ${EndIf}

        FindWindow $3 "#32770" "Setup"
        ${If} $3 <> 0
            System::Call "user32::SendMessage(i $3, i ${WM_COMMAND}, i ${IDOK}, i 0)"
            DetailPrint "OK-Befehl gesendet"
            Sleep 500
            ${Break}
        ${EndIf}
        Sleep 100
    ${Loop}

    System::Call 'Kernel32::SetEnvironmentVariable(t "__COMPAT_LAYER", i 0)'
    DetailPrint "Installationsvorgang abgeschlossen"

    # Clean directories
    RMDir /r "$INSTDIR\EC-APPS"
    RMDir /r "$INSTDIR\EDIABAS"
    RMDir /r "$INSTDIR\NCSEXPER"
    RMDir /r "$INSTDIR\Entwicklungsdaten"
    RMDir /r "$INSTDIR\NFS-Backup"

    # Move directories
    Rename "$TEMP\bmw_setup_files\EC-APPS" "$INSTDIR\EC-APPS"
    Rename "$TEMP\bmw_setup_files\EDIABAS" "$INSTDIR\EDIABAS"
    Rename "$TEMP\bmw_setup_files\NCSEXPER" "$INSTDIR\NCSEXPER"

    # Install OCX files
    Rename "$TEMP\bmw_setup_files\OCX\mscomctl.ocx" "$SYSDIR\mscomctl.ocx"
    Rename "$TEMP\bmw_setup_files\OCX\msflxgrd.ocx" "$SYSDIR\msflxgrd.ocx"
    Rename "$TEMP\bmw_setup_files\OCX\comdlg32.ocx" "$SYSDIR\comdlg32.ocx"

    # Register OCX files
    ExecWait '"$SYSDIR\regsvr32.exe" /s "$SYSDIR\mscomctl.ocx"'
    ExecWait '"$SYSDIR\regsvr32.exe" /s "$SYSDIR\msflxgrd.ocx"'
    ExecWait '"$SYSDIR\regsvr32.exe" /s "$SYSDIR\comdlg32.ocx"'

    # Create default shortcuts
    Rename "$TEMP\bmw_setup_files\SHORTCUTS\Inpa.lnk" "$DESKTOP\Inpa.lnk"
    Rename "$TEMP\bmw_setup_files\SHORTCUTS\Tool32.lnk" "$DESKTOP\Tool32.lnk"
    Rename "$TEMP\bmw_setup_files\SHORTCUTS\NcsExpert.lnk" "$DESKTOP\NcsExpert.lnk"
    Rename "$TEMP\bmw_setup_files\SHORTCUTS\NcsDummy.lnk" "$DESKTOP\NcsDummy.lnk"
    Rename "$TEMP\bmw_setup_files\SHORTCUTS\WinKFP.lnk" "$DESKTOP\WinKFP.lnk"
    Rename "$TEMP\bmw_setup_files\SHORTCUTS\Coding Tool.lnk" "$desktop\Coding Tool.lnk"
SectionEnd

Function .onInstSuccess
    # Cleanup temporary files
    RMDir /r /REBOOTOK "$TEMP\bmw_setup_files"
FunctionEnd

Forum

Der relevante Beitrag zum Installer ist auf BMW-Syndikat.de zu finden. Dort besteht ebenfalls die Möglichkeit, Kommentare zu hinterlassen. Zudem können im Forum weitere Fragen gestellt oder Antworten gesucht werden.